Reemplazar texto usando RegEx en Excel-VBA

Tengo datos en Excel como los siguientes (una fila aquí, una celda en Excel):

07 July 2015 12:02 – 14 July 2015 17:02
12 August 2015 22:02 – 01 September 2015 11:02

Quiero escribir una macro que elimine toda la información de tiempo (por ejemplo, "12:02") dentro de la selección de un usuario (varias celdas) para que se vea así:

07 July 2015 – 14 July 2015
12 August 2015 – 01 September 2015

Cuando todos los "tiempos" eran similares ("00:00"), esta macro funcionó perfectamente:

Sub delete_time() 
 Selection.Replace What:="00:00", Replacement:="", LookAt:=xlPart, _
 SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, _
 ReplaceFormat:=False
End Sub

Pero luego la información de tiempo dejó de ser uniforme, así que decidí usar RegEx. El problema es que no puedo encontrar una forma adecuada de hacer esto en VBA. Probé esta macro:

Sub delete_time()
 Dim RegEx As Object
 Set RegEx = CreateObject("VBScript.RegExp")
 On Error Resume Next
 RegEx.Global = True
 RegEx.Pattern = "\d\d\:\d\d"
 ActiveDocument.Range = _
 RegEx.Replace(ActiveDocument.Range, "")
End Sub

Pero no funcionó. También probé los patrones "[0-9]{2}:[0-9]{2}" y "[0-9][0-9]:[0-9][0-9]", pero nada cambió. Entonces, el problema debe estar en mi malentendido de VBA (soy nuevo en esto).

¿Alguien puede ayudar?

Solución del problema

Un enfoque más rápido sería combinar su RegExpcon una matriz variante:

'Press Alt + F11 to open the Visual Basic Editor (VBE)
'From the Menu, choose Insert-Module.
'Paste the code into the right-hand code window.
'Press Alt + F11 to close the VBE
'In Xl2003 Goto Tools … Macro … Macros and double-click KillDate
Sub KillDate()
 Dim rng1 As Range
 Dim rngArea As Range
 Dim lngRow As Long
 Dim lngCol As Long
 Dim lngCalc As Long
 Dim objReg As Object
 Dim X()
 On Error Resume Next
 Set rng1 = Application.InputBox("Select range for the replacement", "User select", Selection.Address,,,,, 8)
 If rng1 Is Nothing Then Exit Sub
 On Error GoTo 0
 'See Patrick Matthews excellent article on using Regular Expressions with VBA
 Set objReg = CreateObject("vbscript.regexp")
 objReg.Pattern = "\d\d\:\d\d"
 objReg.Global = True
 'Speed up the code by turning off screenupdating and setting calculation to manual
 'Disable any code events that may occur when writing to cells
 With Application
 lngCalc =.Calculation
.ScreenUpdating = False
.Calculation = xlCalculationManual
.EnableEvents = False
 End With
 'Test each area in the user selected range
 'Non contiguous range areas are common when using SpecialCells to define specific cell types to work on
 For Each rngArea In rng1.Areas
 'The most common outcome is used for the True outcome to optimise code speed
 If rngArea.Cells.Count > 1 Then
 'If there is more than once cell then set the variant array to the dimensions of the range area
 'Using Value2 provides a useful speed improvement over Value. On my testing it was 2% on blank cells, up to 10% on non-blanks
 X = rngArea.Value2
 For lngRow = 1 To rngArea.Rows.Count
 For lngCol = 1 To rngArea.Columns.Count
  'replace the leading zeroes
  X(lngRow, lngCol) = objReg.Replace(X(lngRow, lngCol), vbNullString)
 Next lngCol
 Next lngRow
 'Dump the updated array sans leading zeroes back over the initial range
 rngArea.Value2 = X
 Else
 'caters for a single cell range area. No variant array required
 rngArea.Value = objReg.Replace(rngArea.Value, vbNullString)
 End If
 Next rngArea
 'cleanup the Application settings
 With Application
.ScreenUpdating = True
.Calculation = lngCalc
.EnableEvents = True
 End With
 Set objReg = Nothing
End Sub